' This script was originally published in the Exchange Cookbook,         
' (http://www.exchangebookcook.com). Written by Paul Robichaux,          
' Missy Koslosky, and Devin Ganger. Redistributed with permission        
' of the publisher, O'Reilly & Associates.

' This code retrieves the list of all replicas for a specified folder

' ------ SCRIPT CONFIGURATION ------                                 
strComputerName = "<serverName>" 'e.g., "cyclone"                    
strPubFolderPath = "<folderPath>" 'e.g., "/Book Suggestions/"        
' ------ END CONFIGURATION ---------                                 

strE2K3WMIQuery = "winmgmts://" & strComputerName &_                 
  "/root/MicrosoftExchangeV2"                                          

' query for the specific folder we want                              
Set wmiService = GetObject(strE2K3WMIQuery)                          
query = "Select * From Exchange_PublicFolder" & " Where Path='" & _  
  strPubFolderPath & "'"                                               
Set targetFolder = wmiService.ExecQuery(query)                       

' list all of its replicas                                           
For Each folder In targetFolder                                      
  replicaCount = UBound(folder.ReplicaList)+1                          
  WScript.Echo "Folder " & folder.Name & " has " & replicaCount & _    
    " replicas."                                                         
  For i = 0 To replicaCount-1                                          
    WScript.Echo " Replica " & i & "==> " & folder.ReplicaList(i)        
  next                                                                 
Next                                                                 
WScript.Echo "Done processing folders."